mirror of
https://github.com/luksamuk/engine-psx.git
synced 2025-04-28 13:28:02 +03:00
Include git info within builds
This commit is contained in:
Lucas S. Vieira
parent
6f5789edaa
commit
4d4961f729
6 changed files with 436 additions and 30 deletions
|
|
@ -10,6 +10,18 @@ file(GLOB ENGINE_SRC
|
|||
${CMAKE_CURRENT_LIST_DIR}/src/*.c
|
||||
${CMAKE_CURRENT_LIST_DIR}/src/*.s)
|
||||
|
||||
list(APPEND CMAKE_MODULE_PATH
|
||||
"${CMAKE_CURRENT_LIST_DIR}/cmake/")
|
||||
include(GetGitRevisionDescription)
|
||||
get_git_head_revision(GIT_REFSPEC GIT_SHA1)
|
||||
|
||||
string(SUBSTRING "${GIT_SHA1}" 0 7 GIT_SHORTHASH)
|
||||
string(SUBSTRING "${GIT_REFSPEC}" 11 -1 GIT_BRANCH)
|
||||
|
||||
add_definitions("-DGIT_SHA1=\"${GIT_SHA1}\"")
|
||||
add_definitions("-DGIT_REFSPEC=\"${GIT_REFSPEC}\"")
|
||||
add_definitions("-DGIT_COMMIT=\"${GIT_BRANCH}/${GIT_SHORTHASH}\"")
|
||||
|
||||
set(CMAKE_C_FLAGS "-Wall")
|
||||
|
||||
psn00bsdk_add_executable(engine
|
||||
|
|
|
|||
287
cmake/GetGitRevisionDescription.cmake
Normal file
287
cmake/GetGitRevisionDescription.cmake
Normal file
|
|
@ -0,0 +1,287 @@
|
|||
# - Returns a version string from Git
|
||||
#
|
||||
# These functions force a re-configure on each git commit so that you can
|
||||
# trust the values of the variables in your build system.
|
||||
#
|
||||
# get_git_head_revision(<refspecvar> <hashvar> [ALLOW_LOOKING_ABOVE_CMAKE_SOURCE_DIR])
|
||||
#
|
||||
# Returns the refspec and sha hash of the current head revision
|
||||
#
|
||||
# git_describe(<var> [<additional arguments to git describe> ...])
|
||||
#
|
||||
# Returns the results of git describe on the source tree, and adjusting
|
||||
# the output so that it tests false if an error occurs.
|
||||
#
|
||||
# git_describe_working_tree(<var> [<additional arguments to git describe> ...])
|
||||
#
|
||||
# Returns the results of git describe on the working tree (--dirty option),
|
||||
# and adjusting the output so that it tests false if an error occurs.
|
||||
#
|
||||
# git_get_exact_tag(<var> [<additional arguments to git describe> ...])
|
||||
#
|
||||
# Returns the results of git describe --exact-match on the source tree,
|
||||
# and adjusting the output so that it tests false if there was no exact
|
||||
# matching tag.
|
||||
#
|
||||
# git_local_changes(<var>)
|
||||
#
|
||||
# Returns either "CLEAN" or "DIRTY" with respect to uncommitted changes.
|
||||
# Uses the return code of "git diff-index --quiet HEAD --".
|
||||
# Does not regard untracked files.
|
||||
#
|
||||
# Requires CMake 2.6 or newer (uses the 'function' command)
|
||||
#
|
||||
# Original Author:
|
||||
# 2009-2020 Rylie Pavlik <rylie@ryliepavlik.com>
|
||||
# https://ryliepavlik.com/
|
||||
#
|
||||
# Copyright 2009-2013, Iowa State University.
|
||||
# Copyright 2013-2020, Rylie Pavlik
|
||||
# Copyright 2013-2020, Contributors
|
||||
#
|
||||
# SPDX-License-Identifier: BSL-1.0
|
||||
#
|
||||
# Distributed under the Boost Software License, Version 1.0.
|
||||
# (See accompanying file LICENSE_1_0.txt or copy at
|
||||
# http://www.boost.org/LICENSE_1_0.txt)
|
||||
|
||||
if(__get_git_revision_description)
|
||||
return()
|
||||
endif()
|
||||
set(__get_git_revision_description YES)
|
||||
|
||||
# We must run the following at "include" time, not at function call time,
|
||||
# to find the path to this module rather than the path to a calling list file
|
||||
get_filename_component(_gitdescmoddir ${CMAKE_CURRENT_LIST_FILE} PATH)
|
||||
|
||||
# Function _git_find_closest_git_dir finds the next closest .git directory
|
||||
# that is part of any directory in the path defined by _start_dir.
|
||||
# The result is returned in the parent scope variable whose name is passed
|
||||
# as variable _git_dir_var. If no .git directory can be found, the
|
||||
# function returns an empty string via _git_dir_var.
|
||||
#
|
||||
# Example: Given a path C:/bla/foo/bar and assuming C:/bla/.git exists and
|
||||
# neither foo nor bar contain a file/directory .git. This wil return
|
||||
# C:/bla/.git
|
||||
#
|
||||
function(_git_find_closest_git_dir _start_dir _git_dir_var)
|
||||
set(cur_dir "${_start_dir}")
|
||||
set(git_dir "${_start_dir}/.git")
|
||||
while(NOT EXISTS "${git_dir}")
|
||||
# .git dir not found, search parent directories
|
||||
set(git_previous_parent "${cur_dir}")
|
||||
get_filename_component(cur_dir "${cur_dir}" DIRECTORY)
|
||||
if(cur_dir STREQUAL git_previous_parent)
|
||||
# We have reached the root directory, we are not in git
|
||||
set(${_git_dir_var}
|
||||
""
|
||||
PARENT_SCOPE)
|
||||
return()
|
||||
endif()
|
||||
set(git_dir "${cur_dir}/.git")
|
||||
endwhile()
|
||||
set(${_git_dir_var}
|
||||
"${git_dir}"
|
||||
PARENT_SCOPE)
|
||||
endfunction()
|
||||
|
||||
function(get_git_head_revision _refspecvar _hashvar)
|
||||
_git_find_closest_git_dir("${CMAKE_CURRENT_SOURCE_DIR}" GIT_DIR)
|
||||
|
||||
if("${ARGN}" STREQUAL "ALLOW_LOOKING_ABOVE_CMAKE_SOURCE_DIR")
|
||||
set(ALLOW_LOOKING_ABOVE_CMAKE_SOURCE_DIR TRUE)
|
||||
else()
|
||||
set(ALLOW_LOOKING_ABOVE_CMAKE_SOURCE_DIR FALSE)
|
||||
endif()
|
||||
if(NOT "${GIT_DIR}" STREQUAL "")
|
||||
file(RELATIVE_PATH _relative_to_source_dir "${CMAKE_SOURCE_DIR}"
|
||||
"${GIT_DIR}")
|
||||
if("${_relative_to_source_dir}" MATCHES "[.][.]"
|
||||
AND NOT ALLOW_LOOKING_ABOVE_CMAKE_SOURCE_DIR)
|
||||
# We've gone above the CMake root dir.
|
||||
set(GIT_DIR "")
|
||||
endif()
|
||||
endif()
|
||||
if("${GIT_DIR}" STREQUAL "")
|
||||
set(${_refspecvar}
|
||||
"GITDIR-NOTFOUND"
|
||||
PARENT_SCOPE)
|
||||
set(${_hashvar}
|
||||
"GITDIR-NOTFOUND"
|
||||
PARENT_SCOPE)
|
||||
return()
|
||||
endif()
|
||||
|
||||
# Check if the current source dir is a git submodule or a worktree.
|
||||
# In both cases .git is a file instead of a directory.
|
||||
#
|
||||
if(NOT IS_DIRECTORY ${GIT_DIR})
|
||||
# The following git command will return a non empty string that
|
||||
# points to the super project working tree if the current
|
||||
# source dir is inside a git submodule.
|
||||
# Otherwise the command will return an empty string.
|
||||
#
|
||||
execute_process(
|
||||
COMMAND "${GIT_EXECUTABLE}" rev-parse
|
||||
--show-superproject-working-tree
|
||||
WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
|
||||
OUTPUT_VARIABLE out
|
||||
ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
|
||||
if(NOT "${out}" STREQUAL "")
|
||||
# If out is empty, GIT_DIR/CMAKE_CURRENT_SOURCE_DIR is in a submodule
|
||||
file(READ ${GIT_DIR} submodule)
|
||||
string(REGEX REPLACE "gitdir: (.*)$" "\\1" GIT_DIR_RELATIVE
|
||||
${submodule})
|
||||
string(STRIP ${GIT_DIR_RELATIVE} GIT_DIR_RELATIVE)
|
||||
get_filename_component(SUBMODULE_DIR ${GIT_DIR} PATH)
|
||||
get_filename_component(GIT_DIR ${SUBMODULE_DIR}/${GIT_DIR_RELATIVE}
|
||||
ABSOLUTE)
|
||||
set(HEAD_SOURCE_FILE "${GIT_DIR}/HEAD")
|
||||
else()
|
||||
# GIT_DIR/CMAKE_CURRENT_SOURCE_DIR is in a worktree
|
||||
file(READ ${GIT_DIR} worktree_ref)
|
||||
# The .git directory contains a path to the worktree information directory
|
||||
# inside the parent git repo of the worktree.
|
||||
#
|
||||
string(REGEX REPLACE "gitdir: (.*)$" "\\1" git_worktree_dir
|
||||
${worktree_ref})
|
||||
string(STRIP ${git_worktree_dir} git_worktree_dir)
|
||||
_git_find_closest_git_dir("${git_worktree_dir}" GIT_DIR)
|
||||
set(HEAD_SOURCE_FILE "${git_worktree_dir}/HEAD")
|
||||
endif()
|
||||
else()
|
||||
set(HEAD_SOURCE_FILE "${GIT_DIR}/HEAD")
|
||||
endif()
|
||||
set(GIT_DATA "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/git-data")
|
||||
if(NOT EXISTS "${GIT_DATA}")
|
||||
file(MAKE_DIRECTORY "${GIT_DATA}")
|
||||
endif()
|
||||
|
||||
if(NOT EXISTS "${HEAD_SOURCE_FILE}")
|
||||
return()
|
||||
endif()
|
||||
set(HEAD_FILE "${GIT_DATA}/HEAD")
|
||||
configure_file("${HEAD_SOURCE_FILE}" "${HEAD_FILE}" COPYONLY)
|
||||
|
||||
configure_file("${_gitdescmoddir}/GetGitRevisionDescription.cmake.in"
|
||||
"${GIT_DATA}/grabRef.cmake" @ONLY)
|
||||
include("${GIT_DATA}/grabRef.cmake")
|
||||
|
||||
set(${_refspecvar}
|
||||
"${HEAD_REF}"
|
||||
PARENT_SCOPE)
|
||||
set(${_hashvar}
|
||||
"${HEAD_HASH}"
|
||||
PARENT_SCOPE)
|
||||
endfunction()
|
||||
|
||||
function(git_describe _var)
|
||||
if(NOT GIT_FOUND)
|
||||
find_package(Git QUIET)
|
||||
endif()
|
||||
get_git_head_revision(refspec hash)
|
||||
if(NOT GIT_FOUND)
|
||||
set(${_var}
|
||||
"GIT-NOTFOUND"
|
||||
PARENT_SCOPE)
|
||||
return()
|
||||
endif()
|
||||
if(NOT hash)
|
||||
set(${_var}
|
||||
"HEAD-HASH-NOTFOUND"
|
||||
PARENT_SCOPE)
|
||||
return()
|
||||
endif()
|
||||
|
||||
# TODO sanitize
|
||||
#if((${ARGN}" MATCHES "&&") OR
|
||||
# (ARGN MATCHES "||") OR
|
||||
# (ARGN MATCHES "\\;"))
|
||||
# message("Please report the following error to the project!")
|
||||
# message(FATAL_ERROR "Looks like someone's doing something nefarious with git_describe! Passed arguments ${ARGN}")
|
||||
#endif()
|
||||
|
||||
#message(STATUS "Arguments to execute_process: ${ARGN}")
|
||||
|
||||
execute_process(
|
||||
COMMAND "${GIT_EXECUTABLE}" describe --tags --always ${hash} ${ARGN}
|
||||
WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
|
||||
RESULT_VARIABLE res
|
||||
OUTPUT_VARIABLE out
|
||||
ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
|
||||
if(NOT res EQUAL 0)
|
||||
set(out "${out}-${res}-NOTFOUND")
|
||||
endif()
|
||||
|
||||
set(${_var}
|
||||
"${out}"
|
||||
PARENT_SCOPE)
|
||||
endfunction()
|
||||
|
||||
function(git_describe_working_tree _var)
|
||||
if(NOT GIT_FOUND)
|
||||
find_package(Git QUIET)
|
||||
endif()
|
||||
if(NOT GIT_FOUND)
|
||||
set(${_var}
|
||||
"GIT-NOTFOUND"
|
||||
PARENT_SCOPE)
|
||||
return()
|
||||
endif()
|
||||
|
||||
execute_process(
|
||||
COMMAND "${GIT_EXECUTABLE}" describe --dirty ${ARGN}
|
||||
WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
|
||||
RESULT_VARIABLE res
|
||||
OUTPUT_VARIABLE out
|
||||
ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
|
||||
if(NOT res EQUAL 0)
|
||||
set(out "${out}-${res}-NOTFOUND")
|
||||
endif()
|
||||
|
||||
set(${_var}
|
||||
"${out}"
|
||||
PARENT_SCOPE)
|
||||
endfunction()
|
||||
|
||||
function(git_get_exact_tag _var)
|
||||
git_describe(out --exact-match ${ARGN})
|
||||
set(${_var}
|
||||
"${out}"
|
||||
PARENT_SCOPE)
|
||||
endfunction()
|
||||
|
||||
function(git_local_changes _var)
|
||||
if(NOT GIT_FOUND)
|
||||
find_package(Git QUIET)
|
||||
endif()
|
||||
get_git_head_revision(refspec hash)
|
||||
if(NOT GIT_FOUND)
|
||||
set(${_var}
|
||||
"GIT-NOTFOUND"
|
||||
PARENT_SCOPE)
|
||||
return()
|
||||
endif()
|
||||
if(NOT hash)
|
||||
set(${_var}
|
||||
"HEAD-HASH-NOTFOUND"
|
||||
PARENT_SCOPE)
|
||||
return()
|
||||
endif()
|
||||
|
||||
execute_process(
|
||||
COMMAND "${GIT_EXECUTABLE}" diff-index --quiet HEAD --
|
||||
WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
|
||||
RESULT_VARIABLE res
|
||||
OUTPUT_VARIABLE out
|
||||
ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
|
||||
if(res EQUAL 0)
|
||||
set(${_var}
|
||||
"CLEAN"
|
||||
PARENT_SCOPE)
|
||||
else()
|
||||
set(${_var}
|
||||
"DIRTY"
|
||||
PARENT_SCOPE)
|
||||
endif()
|
||||
endfunction()
|
||||
48
cmake/GetGitRevisionDescription.cmake.in
Normal file
48
cmake/GetGitRevisionDescription.cmake.in
Normal file
|
|
@ -0,0 +1,48 @@
|
|||
#
|
||||
# Internal file for GetGitRevisionDescription.cmake
|
||||
#
|
||||
# Requires CMake 2.6 or newer (uses the 'function' command)
|
||||
#
|
||||
# Original Author:
|
||||
# 2009-2023 Rylie Pavlik <rylie@ryliepavlik.com>
|
||||
# https://ryliepavlik.com/
|
||||
# Iowa State University HCI Graduate Program/VRAC
|
||||
#
|
||||
# Copyright 2009-2012, Iowa State University
|
||||
# Copyright 2011-2023, Contributors
|
||||
#
|
||||
# Distributed under the Boost Software License, Version 1.0.
|
||||
# (See accompanying file LICENSE_1_0.txt or copy at
|
||||
# http://www.boost.org/LICENSE_1_0.txt)
|
||||
#
|
||||
# SPDX-License-Identifier: BSL-1.0
|
||||
|
||||
set(HEAD_HASH)
|
||||
|
||||
file(READ "@HEAD_FILE@" HEAD_CONTENTS LIMIT 1024)
|
||||
|
||||
string(STRIP "${HEAD_CONTENTS}" HEAD_CONTENTS)
|
||||
if(HEAD_CONTENTS MATCHES "ref")
|
||||
# named branch
|
||||
string(REPLACE "ref: " "" HEAD_REF "${HEAD_CONTENTS}")
|
||||
if(EXISTS "@GIT_DIR@/${HEAD_REF}")
|
||||
configure_file("@GIT_DIR@/${HEAD_REF}" "@GIT_DATA@/head-ref" COPYONLY)
|
||||
else()
|
||||
if(EXISTS "@GIT_DIR@/packed-refs")
|
||||
configure_file("@GIT_DIR@/packed-refs" "@GIT_DATA@/packed-refs"
|
||||
COPYONLY)
|
||||
file(READ "@GIT_DATA@/packed-refs" PACKED_REFS)
|
||||
if(${PACKED_REFS} MATCHES "([0-9a-z]*) ${HEAD_REF}")
|
||||
set(HEAD_HASH "${CMAKE_MATCH_1}")
|
||||
endif()
|
||||
endif()
|
||||
endif()
|
||||
else()
|
||||
# detached HEAD
|
||||
configure_file("@GIT_DIR@/HEAD" "@GIT_DATA@/head-ref" COPYONLY)
|
||||
endif()
|
||||
|
||||
if(NOT HEAD_HASH)
|
||||
file(READ "@GIT_DATA@/head-ref" HEAD_HASH LIMIT 1024)
|
||||
string(STRIP "${HEAD_HASH}" HEAD_HASH)
|
||||
endif()
|
||||
|
|
@ -4,6 +4,20 @@
|
|||
#include <psxgpu.h>
|
||||
#include <psxgte.h>
|
||||
|
||||
// These definitions should be given by CMake
|
||||
#ifndef GIT_SHA1
|
||||
#define GIT_SHA1 "UNKNOWN"
|
||||
#endif
|
||||
|
||||
#ifndef GIT_REFSPEC
|
||||
#define GIT_REFSPEC "UNKNOWN"
|
||||
#endif
|
||||
|
||||
#ifndef GIT_COMMIT
|
||||
#define GIT_COMMIT "UNKNOWN"
|
||||
#endif
|
||||
|
||||
|
||||
#define BCD_TO_DEC(x) (((x & 0xF0) >> 4) * 10 + (x & 0x0F))
|
||||
#define SIGNUM(x) (x < 0 ? -1 : 1)
|
||||
#define MAX(x, y) (x > y ? x : y)
|
||||
|
|
|
|||
|
|
@ -11,6 +11,7 @@
|
|||
#include "screens/fmv.h"
|
||||
#include "sound.h"
|
||||
#include "util.h"
|
||||
#include "timer.h"
|
||||
|
||||
#define CHOICE_MODELTEST 5
|
||||
#define CHOICE_TITLE 6
|
||||
|
|
@ -57,7 +58,7 @@ screen_levelselect_load()
|
|||
data->bg_state = 0;
|
||||
data->bg_timer = BG_PAUSE;
|
||||
|
||||
sound_play_xa("\\BGM\\MNU001.XA;1", 0, 0, 0);
|
||||
sound_play_xa("\\BGM\\MNU001.XA;1", 0, 0, 0); // 2600
|
||||
}
|
||||
|
||||
void
|
||||
|
|
@ -136,6 +137,10 @@ screen_levelselect_update(void *d)
|
|||
scene_change(SCREEN_LEVEL);
|
||||
}
|
||||
}
|
||||
|
||||
uint32_t elapsed_sectors;
|
||||
sound_xa_get_elapsed_sectors(&elapsed_sectors);
|
||||
if(elapsed_sectors >= 2600) sound_stop_xa();
|
||||
}
|
||||
|
||||
void
|
||||
|
|
@ -143,6 +148,17 @@ screen_levelselect_draw(void *d)
|
|||
{
|
||||
screen_levelselect_data *data = (screen_levelselect_data *)d;
|
||||
|
||||
if(debug_mode) {
|
||||
uint32_t elapsed_sectors;
|
||||
sound_xa_get_elapsed_sectors(&elapsed_sectors);
|
||||
FntPrint(-1, "BRANCH: %-21s %4s %3d\n",
|
||||
GIT_COMMIT,
|
||||
GetVideoMode() == MODE_PAL ? "PAL" : "NTSC",
|
||||
get_frame_rate());
|
||||
FntPrint(-1, " %08u\n", elapsed_sectors);
|
||||
FntFlush(-1);
|
||||
}
|
||||
|
||||
// Draw background
|
||||
for(uint16_t y = 0; y < SCREEN_YRES; y += 32) {
|
||||
for(uint16_t x = 0; x < SCREEN_XRES; x += 48) {
|
||||
|
|
|
|||
|
|
@ -10,10 +10,13 @@
|
|||
#include "screen.h"
|
||||
#include "sound.h"
|
||||
/* #include "model.h" */
|
||||
#include "timer.h"
|
||||
|
||||
#include "screens/fmv.h"
|
||||
#include "screens/level.h"
|
||||
|
||||
extern int debug_mode;
|
||||
|
||||
typedef struct {
|
||||
int32_t prect_x;
|
||||
int32_t prect_y;
|
||||
|
|
@ -122,6 +125,7 @@ screen_title_load()
|
|||
/* data->planet.scl.vy = */
|
||||
/* data->planet.scl.vz = 2048; */
|
||||
|
||||
printf("Commit: %s:%s\n", GIT_SHA1, GIT_REFSPEC);
|
||||
|
||||
sound_play_xa("\\BGM\\MNU001.XA;1", 0, 1, 0);
|
||||
|
||||
|
|
@ -138,8 +142,17 @@ screen_title_unload(void *)
|
|||
void
|
||||
screen_title_update(void *d)
|
||||
{
|
||||
if((pad_pressing(PAD_L1) && pad_pressed(PAD_R1)) ||
|
||||
(pad_pressed(PAD_L1) && pad_pressing(PAD_R1))) {
|
||||
debug_mode = (debug_mode + 1) % 3;
|
||||
}
|
||||
|
||||
screen_title_data *data = (screen_title_data *)d;
|
||||
|
||||
uint32_t elapsed_sectors;
|
||||
sound_xa_get_elapsed_sectors(&elapsed_sectors);
|
||||
if(elapsed_sectors >= 950) sound_stop_xa();
|
||||
|
||||
/* data->planet.rot.vz -= 24; */
|
||||
|
||||
data->pos.vx -= 1;
|
||||
|
|
@ -355,6 +368,21 @@ screen_title_draw(void *d)
|
|||
LERPC(data->rgb_count, 104),
|
||||
LERPC(data->rgb_count, 200));
|
||||
|
||||
char buffer[255] = { 0 };
|
||||
|
||||
if(debug_mode) {
|
||||
uint32_t elapsed_sectors;
|
||||
sound_xa_get_elapsed_sectors(&elapsed_sectors);
|
||||
FntPrint(-1, "BRANCH: %-21s %4s %3d\n",
|
||||
GIT_COMMIT,
|
||||
GetVideoMode() == MODE_PAL ? "PAL" : "NTSC",
|
||||
get_frame_rate());
|
||||
FntPrint(-1, "%11s %8s %08u\n",
|
||||
__DATE__, __TIME__, elapsed_sectors);
|
||||
FntFlush(-1);
|
||||
}
|
||||
|
||||
|
||||
|
||||
screen_title_drawtitle(data);
|
||||
screen_title_drawprl(data);
|
||||
|
|
@ -370,9 +398,10 @@ screen_title_draw(void *d)
|
|||
screen_title_drawtxt(data, 5, CENTERX + 60, 208);
|
||||
}
|
||||
|
||||
char buffer[255] = { 0 };
|
||||
snprintf(buffer, 255, "%s %s", __DATE__, __TIME__);
|
||||
int16_t x = SCREEN_XRES - (strlen(buffer) * 8) - 8;
|
||||
draw_text(x, SCREEN_YRES - 16, 0, buffer);
|
||||
int16_t x;
|
||||
|
||||
snprintf(buffer, 255, "v0.1 Beta");
|
||||
x = SCREEN_XRES - (strlen(buffer) * 8) - 8;
|
||||
draw_text(x, SCREEN_YRES - 14, 0, buffer);
|
||||
}
|
||||
}
|
||||
|
|
|
|||
Loading…
Add table
Add a link
Reference in a new issue